implement billboard shader and add new example

openVulkanoCpp/Shader/billboard.frag

@@ -0,0 +1,9 @@
+#version 450
+
+layout(location = 0) in vec4 color;
+layout(location = 0) out vec4 outColor;
+
+void main()
+{
+    outColor = color;
+}

openVulkanoCpp/Shader/billboard.vert

@@ -0,0 +1,55 @@
+#version 450
+
+layout(location = 0) in vec3 pos;
+layout(location = 1) in vec3 normal;
+layout(location = 5) in vec4 color;
+layout(location = 0) out vec4 outColor;
+
+layout(set = 0, binding = 0) uniform NodeData
+{
+	mat4 world;
+} node;
+
+layout(set = 1, binding = 0) uniform CameraData
+{
+    mat4 viewProjection;
+    mat4 view;
+    mat4 projection;
+    vec4 camPos;
+} cam;
+
+layout(set = 2, binding = 0) uniform BillboardData
+{
+   vec2 size;
+   vec2 windowSize;
+   bool isFixedSize;
+} billboardInfo;
+
+void main() {
+    if (!billboardInfo.isFixedSize)
+    {
+        mat4 mv = cam.view * node.world;
+
+        mv[0][0] = 1;
+        mv[0][1] = 0;
+        mv[0][2] = 0;
+    
+        mv[1][0] = 0;
+        mv[1][1] = 1;
+        mv[1][2] = 0;
+    
+        mv[2][0] = 0;
+        mv[2][1] = 0;
+        mv[2][2] = 1;
+    
+        gl_Position = cam.projection * mv * vec4(pos, 1);
+    }
+    else
+    {   
+        vec4 billboardPos = vec4(0, 0, 0, 1);
+        vec4 viewPos = cam.view * node.world * billboardPos;
+        float dist = -viewPos.z;
+        gl_Position = cam.projection * (viewPos + vec4(pos.xy*dist*0.2,0,0));
+    }
+    outColor = color;
+}

openVulkanoCpp/Shader/billboardFromSinglePoint.geom

@@ -0,0 +1,75 @@
+#version 450
+
+layout(points) in;
+layout(triangle_strip, max_vertices = 4) out;
+
+layout(set = 0, binding = 0) uniform NodeData
+{
+	mat4 world;
+} node;
+
+layout(set = 1, binding = 0) uniform CameraData
+{
+    mat4 viewProjection;
+    mat4 view;
+    mat4 projection;
+    vec4 camPos;
+} cam;
+
+layout(set = 2, binding = 0) uniform BillboardData
+{
+   vec2 size;
+   vec2 windowSize;
+   bool isFixedSize;
+} billboardInfo;
+
+layout(location = 0) out vec4 color;
+
+layout(location = 0) in VS_OUT {
+    vec4 color;
+} gs_in[];
+
+void main() {
+    // The desired point for the billboard
+    vec3 pos = gl_in[0].gl_Position.xyz;
+    
+    if(!billboardInfo.isFixedSize)
+    {
+        vec3 cameraRight = normalize(vec3(cam.view[0][0], cam.view[1][0], cam.view[2][0]));
+        vec3 cameraUp = normalize(vec3(cam.view[0][1], cam.view[1][1], cam.view[2][1]));
+        const vec2 offsets[4] = {
+            vec2(0.5, -0.5),
+            vec2(0.5, 0.5),
+            vec2(-0.5, -0.5),
+            vec2(-0.5, 0.5)
+        };
+
+        for (int i = 0; i < 4; i++)
+        {
+            vec2 scaledSize = billboardInfo.size / length(billboardInfo.size);
+            gl_Position = cam.viewProjection * vec4(pos + cameraRight * offsets[i].x * scaledSize.x + cameraUp * offsets[i].y * scaledSize.y, 1.0);
+            color = gs_in[0].color;
+            EmitVertex();
+        }
+        EndPrimitive();
+    }
+    else
+    {
+        const vec2 offsets[4] = {
+            vec2(-0.5, -0.5),
+            vec2(-0.5, 0.5),
+            vec2(0.5, -0.5),
+            vec2(0.5, 0.5)
+        };
+
+        for (int i = 0; i < 4; i++)
+        {
+            gl_Position = cam.viewProjection * vec4(pos, 1);
+            gl_Position /= gl_Position.w;
+            gl_Position.xy += offsets[i] * vec2(billboardInfo.size.x/billboardInfo.windowSize.x, billboardInfo.size.x/billboardInfo.windowSize.y);
+            color = gs_in[0].color;
+            EmitVertex();
+        }
+        EndPrimitive();
+    }
+}

openVulkanoCpp/Shader/billboardFromSinglePoint.vert

@@ -0,0 +1,35 @@
+#version 450
+
+layout(location = 0) in vec3 pos;
+layout(location = 1) in vec3 normal;
+layout(location = 5) in vec4 color;
+
+layout(location = 0) out VS_OUT {
+    vec4 color;
+} vs_out;
+
+layout(set = 0, binding = 0) uniform NodeData
+{
+	mat4 world;
+} node;
+
+layout(set = 1, binding = 0) uniform CameraData
+{
+    mat4 viewProjection;
+    mat4 view;
+    mat4 projection;
+    vec4 camPos;
+} cam;
+
+layout(set = 2, binding = 0) uniform BillboardData
+{
+   vec2 size;
+   vec2 windowSize;
+   bool isFixedSize;
+} billboardInfo;
+
+void main() {
+	// single point
+	gl_Position = node.world * vec4(pos, 1);
+    vs_out.color = color;
+}